Slouching Towards Bedlam — 62 of 76

Section 4 - Platform

The description of Platform is "A wide flat plane of solid wood, above which - at eye level - hangs the noose. Just below there is the thin outline of trapdoor, perhaps ten feet by eight. Directly beside the stairs, off to the left, an automaton waits, unmoving."

The automaton is scenery in Platform. "The automaton stands directly beside the stairs - a grotesque parody of a man. Its heavy torso, only partially enclosed in black robes, grows right from the stage floor, the cogs and gears that serve as its organs exposed. Its massive arms grip an iron switch.[paragraph break]A red button sits on the platform directly beside it." Understand "man", "executioner", "torso", "robes", "cogs", "gears", "executioner's", "mask" as the automaton.

The red button is scenery in Platform. The red button has a truth state called activated. The activated of the red button is false. The description of the red button is "A small, red button, set into the stage floor.[if the activated of the red button is true] It softly glows with an inherent light."

Instead of pushing the red button:

If the activated of the red button is false:

now the activated of the red button is true;

say "The button begins to glow. Beside it, the automaton pulls itself upright with a whir and a groan as the floor rumbles with the distinct sound of a steam engine springing to life beneath the stage.";

otherwise:

now the activated of the red button is false;

say "The button stops glowing as both the automaton and the unseen steam engine shut off."

The noose is scenery in Platform. The noose has a truth state called worn. The worn of the noose is false. The description of the noose is "The noose is made of new, stout rope. A closer inspection reveals a series of fine wires woven into the knot. These run up the length of the rope, over the beams, down along the back of the stage and vanish beneath the automaton." Understand "rope", "wire", "wires" as the noose.

Instead of jumping while the Platform encloses the player:

if the worn of the noose is true:

say "The edge of the platform cannot be reached while still wearing the noose.";

otherwise:

say "It's a short enough jump to the ground...";

try going south;

Instead of pushing the red button when the worn of the noose is true:

say "The button is too far away to reach while wearing the noose."

A procedural rule when wearing or taking off the noose:

ignore the carrying requirements rule;

ignore the can't wear what's not held rule.

Instead of wearing the noose:

if the worn of the noose is false:

say "The noose slips easily enough over the head.";

now the worn of the noose is true;

if the activated of the red button is true:

say "[line break]The fit is loose at first, then with a noise from above the wires pull upward causing it to tighten. An unseen bell gongs from beneath, shaking the floorboards.[paragraph break]With a rapid series of clicks, cogs grinding against cogs, the automaton turns its head towards the empty street. There is a hiss of static, then a recorded voice speaks: [paragraph break]'All good people, pray heartily unto God for this poor sinner who is now going to his death, for whom the great bell tolls.'[paragraph break]More clicks, and the automaton turns to face the noose. The static sounds like steam leaking.[paragraph break]'You that are condemned to die, repent with lamentable tears; ask mercy of the Lord for the salvation of your soul. You have one minute remaining of your life. You may use this time to beg forgiveness of God and the Good People of this Great Kingdom, or to make your peace with your maker in silence. Your minute begins now.'[paragraph break]A minute to reflect. A minute to regret. A minute to repent.[paragraph break]Suddenly, the trap door snaps open. The landscape rises up in a rush, a quick jerk, and then, darkness.[paragraph break]";

now the player is dead;

choose an ending;

otherwise:

say "That is already worn."

Instead of taking off the noose:

if the worn of the noose is true:

say "The noose slips off and once again swings empty in the breeze.";

now the worn of the noose is false;

otherwise:

say "That isn't being worn."

Instead of going when the worn of the noose is true:

say "That's impossible while still wearing the noose."

The trap door is scenery in Platform. "Currently closed, it covers a good deal of the platform directly beneath the noose." Instead of opening the trap door, say "The door will not open to any amount of force." Instead of attacking the trap door, say "The door holds strong. It is too sturdy to be opened in such a manner."